Вийшло відео до сьомого епізоду Tux In Troubles Dev.log

 Ну нарешті!

Нарешті я зміг виділити час і зняти й змонтувати раніше анонсоване відео до сьомого епізоду по розробці гри!

То ж усі, хто цікавиться цією темою - тримайте:

P.S. Не забудьте підписатися на канал! Вам не складно, а мені приємно!

 

Tux In Troubles Ep.07 вже на сайті!

Нарешті вийшов сьомий епізод! А в ньому:

 

виправимо помилки, допущені в попередньому епізоді

розробимо клас базового ігрового об'єкта

реалізуємо обробку усіх ігрових об'єктів на основі базового класу на рівні фреймворку

реалізуємо завантажувач параметрів ігрового об'єкта

спробуємо переписати демо проект з використанням базових об'єктів

Якщо хочете, щоб нові епізоди виходили частіше, не забувайте підписатись на мій Youtube-канал!

6 епізод вже вийшов!

 Вітаю всіх читачів мого блоґу!

Щойно вийшов в публічний доступ 6 епізод розробки "Tux In Troubles".

В цьому епізоді ми створимо ефективний менеджер зображень, який дозволить завантажувати і виводити як ціле зображення, так і його фрагмент в заданому місці. До завантажених зображень можна звертатись по унікальному текстовому ідентифікатору. Ми можемо використовувати таку кількість зображень, яка потрібна для нашої гри.

Звісно, цей менеджер зображень інтегруємо у фреймворк і все разом протестуємо з реальними спрайтшітами.

Відео по цьому епізоду: 

Не забувайте підписатись на мій канал Youtube, а також написати в коментарях що можна покращити або змінити, та який контент Вас краще цікавить - так я буду знати над чим мені працювати далі та в яку сторону розвивати цей блоґ і канал.

На підході новий епізод!

 Вітаю всіх читачів мого блоґу!

Як і обіцяв, продовжую роботу над проектом "Tux In Troubles", і вже майже готовий наступний, 6-й епізод, де ми створимо менеджер текстур та інтегруємо його до фреймворку.

Сирці до епізоду вже доступні на Github, текст проходить контрольну вичитку і вже записано відео, лишилось лише завершити монтаж.

Tux In Troubles - ep.05

 Нарешті!

Повністю готовий епізод розробки Tux In Troubles, і поки завантажується відео на Youtube, я коротко розповім що заважало мені довгий час випустити новий епізод.

По-перше, з часу попереднього епізоду я досить сильно був зайнятий розробкою інших програм.

По-друге, було багато інших справ, які не можна було відкласти і які забирали досить багато ресурсів.

По-третє, почалась війна, яка все ще триває (не забуваємо донатити на ЗСУ - посилання по стрічці в верхньому лівому кутку сайту). Ми однозначнно переможемо, це лише питання часу.

Але життя триває, і відповідно я вирішив продовжувати розробку. Від Вас залежить, наскільки інтенсивно я буду рухатись вперед по Дорожній карті - чим більше переглядів, лайків/дизлайків, коментарів буде під публікаціями та відео, чим більше підписок на каналі, тим швидше будуть виходити нові епізоди.

До речі, наскільки детально потрібно в відео описувати процес розробки? Чи достатньо буде повідомити що і для чого роблю, а як реалізовую не коментувати? Напишіть свої думки в коментарях.

Новий епізод після тривалої перерви - вже скоро!

 Вітаю всіх читачів мого блоґу!

Вже більше року не було нових епізодів Tux In Troubles, і я вже сам думав що розробка навряд чи буде продовжуватись. Але не все так погано - звісно, часу дуже не вистачає, проте я вирішив продовжити розробку. І вже майже повністю готовий новий епізод, залишилося завершити монтаж відео. Сирці до епізоду вже виложено на Github (як завждти, в розділі "Releases"), текст проходить останні вичитки і вже на початок осені планую все це опублікувати.

Також є плани на наступний, шостий епізод, де почнемо працювати з графікою, тож не пропустіть - додайте сайт в закладки, підпишіться на мій канал на Youtube та відреагуйте лайком/дизлайком на відео попередніх епізодів, а ще краще напишіть щось в коментарях - так я буду знати, чи потрібно продовжувати розробку цієї гри, а також що можна додати/змінити у вже реалізованому функціоналі. Хоча в мене досить великий стаж програміста, але в геймдеві я новачок, тому для мене розробка гри теж в новинку і я теж вчусь разом з Вами.

Тож підтримуйте контент українською мовою, не забувайте донатити на ЗСУ та допомагати волонтерам, і ми обов'язково переможемо! Все буде Україна!

Tux In Troubles: Ep.04

 Вітаю всіх читачів свого блоґу.

Сьогодні знову неділя, і нарешті є новий епізод, відео до якого я виклав на Youtube ще в п'ятницю (тож варто підписатись на мій канал і натиснути на дзвіночок, щоб отримувати сповіщення про нові відео).

Я пам'ятаю, що відстаю вже на два епізоди, тому по мірі можливостей та часу буду намагатись це надолужити.

Ще раз нагадую, що усі епізоди доступні в розділі "Підручники", а сирці на Github, де в розділі "Releases" можна скачати відповідний до кожного епізоду архів.

Якщо в когось є якісь зауваження або пропозиції, не соромтесь, залишайте коментарі або під матеріалом блоґу, або під відео на Youtube - конструктивна критика теж вітається.

Tux In Troubles - next episode

 Вітаю всіх читачів блоґу.

Від незалежних від мене обставин вихід нового епізоду минулих вихідних не відбувся, але розробка не припинилась остаточно.

Станом на сьогодні є дві новини - хороша і не зовсім. Почну з другої - цих вихідних епізоду все ще не буде. А хороша - епізод вже записано, лишилось змонтувати відео і дописати відповідну статтю, а сирці вже опубліковано на Github. Тому найближчими днями це все буде опубліковано, 

Наразі я зробив на Github релізи для кожного епізоду окремо, тому посилання на сирці будуть оновлені і можна буде скачати лише відповідний до епізоду архів.

Затримка епізоду

 Вітаю всіх читачів мого блоґу!

Сьогодні знову неділя, і знову пора публікувати наступний епізод розробки.

Проте, нажаль, цього тижня в мене було зовсім мало часу, і новий епізод вийде трохи з запізненням. Я буду намагатись напротязі наступного тижня доробити і опублікувати не один, а два епізоди, щоб повернутись до звичайного графіку.

Можливо, хтось має якісь пропозиції чи зауваження до розробки гри і фреймворка, дайте знати в коментах під публікаціями чи під відео на Youtube.

Плейліст епізодів на Youtube

Tux In Troubles: Ep.03

Вітаю всіх читачів свого блоґу.

В цьому епізоді сформуємо базовий клас фреймворка, в який перенесемо існуючий функціонал.

Епізод щоденнику вже доступний у розділі "Підручники", відео можна переглянути на моєму каналі Youtube. 

Tux In Troubles: ep.02

 Вітаю всіх читачів свого блоґу.

Продовжуємо розробку, і сьогодні ми переробимо код, який написали в попередньому епізоді, виділивши окремі логічні частини.

Епізод щоденнику вже доступний у розділі "Підручники", відео можна переглянути на моєму каналі Youtube.

Якщо ти ще не підписався на мій канал, то саме час це зробити зараз.

Tux In Troubles: ep.01

Вітаю усіх читатів мого блоґу!

Сьогодні продовжую публікувати щоденники розробки гри з використанням SDL 2.0.

Це перший епізод, в якому ми створимо просте вікно і запустимо безкінечний цикл, вихід з якого відбувається при закритті вікна.

Також я записав відео, як налаштувати середовище розробки на роботу з бібліотекою SDL 2.0 та розділити окремо сирці проекту, проміжні файли компіляції та вихідний виконуваний файл.

В наступному епізоді спробуємо розділити наш код на окремі логічні фрагменти і виділити кістяк майбутньої гри.

Підручник по розробці ігрового фреймворка і гри на його основі з використанням бібліотеки SDL 2.0

Вітаю усіх читачів свого блоґу.

Сьогодні дуже велике християнське свято - Воскресіння Христове. Проте я не відступаю від своєї традиції і продовжую кожної неділі публікувати нові матеріали.

Саме сьогодні починаю цикл нових авторських матеріалів по розробці цілого фреймворка для розробки відеоігор, про що я згадував у попередніх публікаціях. Я назвав його Tux in Troubles SDL 2.0 (Dangerous Dave remake), і починаю його з нульового епізоду, в якому розповідаю що, чому і як буду робити, а також що для цього буду використовувати.

Веселих усім вихідних! Христос воскрес! Воістину воскрес!

З наступаючим Новим роком!

 

Вітаю усіх читачів мого блоґу.

Хочу усіх привітати з наступаючими Новорічними святами та повідомити наступну новину.  Я зв'язвася з автором сайту Free Pascal Meets SDL, щоб попросити його дозволу на переклад циклу матеріалів по роботі з бібліотекою SDL2 за допомогою Free Pascal та Lazarus. Відразу по отриманню відповіді почну публікувати переклади з посиланням на оригінальний матеріал.

Маю прохання, якщо в моєму варіанті перекладу будуть неточності або помилки, повідомляти про це в коментах під відповідним матеріалом, буду намагатись оперативно виправляти.

Розробка фреймворка для 2-Д відеоігор на основі мультимедійної бібліотеки SDL2. Частина 4. Повноцінне вікно.

Зміна заголовку вікна

Ми вже навчились програмно встановлювати повноекранний режим, тепер я розповім, як можна програмно змінити заголовок вікна. Це боває корисно, наприклад, коли в віконному режимі гри ти захочеш вивести назву або номер рівня, який зараз завантажений, чи ще якусь довідкову інформацію. SDL дозволяє це зробити викликом відповідної функції - SDL_SetWindowTitle(), параметрами якої є вказівник на вікно, в якому буде мінятись заголовок, і новий текст заголовку. Щоб це спрацювало, перейди в метод нашого класу SetCaption і в самий кінець допиши наступний код:

if fSDLWindow<>nil then SDL_SetWindowTitle(fSDLWindow,PChar(UTF8String(FCaption)));

Перевірка оператором if нам потрібна для того, щоб не виникло помилки зміни заголовку вікна до того, як вікно буде створене. Аналогічну перевірку також потрібно поставити і при зміні повноекранного/віконного режимів.

Зміна геометрії вікна

Ти вже знаєш як встановити повноекранний режим, але що робити, коли потрібно змінити розміри вікна під час виконання програми? Як це можна реалізувати засобами SDL? Спробуємо розібратись разом.

Пам’ятаєш, трошки раніше ми вже додали властивості ширини і висоти вікна? Я обіцяв, що ми ще повернемось до цього пізніше, і це “пізніше” настало.

Щоб вікно могло змінювати розміри, необхідно в першу чергу при створенні вказати відповідний прапорець SDL_WINDOW_RESIZABLE (див. таблицю вище). Функція створення вікна прийме наступний вигляд:

   fSDLWindow:=SDL_CreateWindow(PChar(Utf8String(Caption)),
                  SDL_WINDOWPOS_UNDEFINED,
                  SDL_WINDOWPOS_UNDEFINED,
                  Height,
      Width,
                  SDL_WINDOW_SHOWN or SDL_WINDOW_RESIZABLE); 

Тепер після того, як вікно з’явиться на екрані, можна мишкою змінювати його розміри, але як дізнатись програмно, які будуть ширина і висота вікна після зміни його розмірів? SDL для роботи з вікном має окремий тип подій, SDL_WINDOW_EVENT, а конкретно для зміни розмірів вікна - SDL_WINDOWEVENT_SIZE_CHANGED, а в додаткових полях структури події можна взяти інформацію про нові розміри вікна. Якщо в обробку подій нашого класу додати ще один if, програмний код стане важче сприйматись, тому я вирішив використати оператор вибору case, тому що ще потрібно додати декілька подій, обробку яких теж будемо реалізовувати. В мене вийшов наступний код для методу обробки подій:

procedure TGOEngine.DoEvents;
begin
   if SDL_PollEvent(fSDLEvent)=1 then begin
      case fSDLEvent^.type_ of
      //відловлюємо подію закриття вікна
      //і встановлюємо ознаку виконання в false для переривання ігрового циклу
SDL_QUITEV: fRunning:=false;
SDL_KEYUP: begin
      //відловлюємо Alt+Enter для зміни режиму
         if (fSDLEvent^.key.keysym.sym = SDLK_RETURN) and ((fSDLEvent^.key.keysym._mod and KMOD_ALT) <> 0) then
            IsFullScreen:=not IsFullScreen;
       end;
      //обробка подій вікна
SDL_WINDOWEVENT: begin
        case fSDLEvent^.window.event of
   //зміна розмірів вікна
     SDL_WINDOWEVENT_SIZE_CHANGED: begin
            Width:=fSDLEvent^.window.data1;
            Height:=fSDLEvent^.window.data2;
           end;
        end;
       end;
      end;
   end;
end;

Щоб перевірити, чи дійсно ми дізнались нові розміри вікна, спробуємо їх вивести в заголовок. Для цього в методи зміни висоти і ширини вікна просто додай наступний рядок в самому кінці обох методів (після тестування не забудь їх видалити):

Caption:=’Ширина:’+IntToStr(FWidth)+’/Висота:’+IntToStr(FHeight);

Тепер спробуй запустити програму і змінити розміри вікна, в заголовку тобі мають відображатись поточні розміри.

Обробка інших корисних подій.

Основні потрібні методи ми вже розглянули, але при розробці ігор нам може знадобитись ще дещо корисне. Розглянемо по порядку.

Найперше - коли вікно отримує або втрачає фокус. Під час гри це може знадобитись для встановлення паузи. Також встановити паузу може бути потрібно при згортанні вікна в трей. Для цього додамо нову властивість:

property Active : Boolean read

і знову натиснемо Ctrl+Shift+C - ця властивість буде доступною лише для читання, а її стан буде змінюватись при відловлюванні певних подій вікна, які зараз ми додамо. Тож переходь в метод DoEvents() і дописуй наступний код відразу після зміни розмірів вікна:

      //втрата фокусу, згортання вікна
     SDL_WINDOWEVENT_FOCUS_LOST,
     SDL_WINDOWEVENT_MINIMIZED: FActive:=false;
     //отримання фокусу
     SDL_WINDOWEVENT_TAKE_FOCUS: FActive:=true;

Ми поки що лише перевіряємо втрату фокусу, згортання вікна і отримання вікном фокусу (згорнуте вікно не може отримати фокус).

Коли нам будуть потрібні інші події вікна щоб на них зреагувати, ти вже знаєш як і куди їх додати.

Апаратне прискорення та інші додаткові “плюшки”

Ну як же в відеоіграх і без апаратного прискорення! В SDL за це відповідає рендерер, при створенні якого потрібно вказати відповідний прапорець. Взагалі, можна вказати декілька прапорців через логічний оператор OR. Можливі варіанти описані в документації по SDL, але тут ми не будемо розглядати їх усі в деталях. Отже, я пропоную просто винести окрему властивість, яка буде відповідати за апаратне прискорення:

    //апаратне прискорення
    property HardwareAcceleration : Boolean default true;

Знову натискуй вже звичне Ctrl+Shift+C, і потрібний код згенерується автоматично. Але потрібно пам’ятати, що встановлення апаратного прискорення можливе лише при створенні рендерера, тому бажано додати перевірку і виводити відповідне повідомлення користувачеві:

  if (fSDLRenderer<>nil) then begin
      SDL_ShowSimpleMessageBox(SDL_MESSAGEBOX_INFORMATION,
        ’Warning!’,
        ’Настройки будуть задіяні після перезапуску!’,
        nil);
  end;

В документації по SDL описано усі можливі прапорці, але я всіх тут розглядати не буду, їх можна при потребі легко додати в клас. Оскільки прапорців може бути декілька в різних комбінаціях, я вирішив зробити два додаткових поля для внутрішнього використання: в одному будуть прапорці для створення вікна, а в іншому - для створення рендерера:

    //прапорці для вікна
    fWindowFlags : Integer;
    //прапорці для рендерера
    fRendererFlags : Integer;

Початкова ініціалізація цих прапорців буде відбуватись перед створенням вікна і рендерера на основі встановлених відповідних властивостей. Але тепер параметрів стало більше, і методи можуть використовуватись різні, тому давай на цьому питанні зупинимось детальніше.

Перегрузка методу ініціалізації

Ми вже додали досить багато властивостей в наш клас, але ніяк не змінювали метод ініціалізації. Як на мене, можна ініціалізувати вікно кількома способами:

• передача потрібних параметрів під час виклику методу ініціалізації;
• встановлення потрібних властивостей після створення об’єкта шляхдм присвоєння значень відповідним полям, після чого викликати метод ініціалізації;
• при виклику методу ініціалізації вказувати шлях і назву файлу, де збережені параметри ініціалізації.

Завдячуючи такій можливості, як перегрузка методів, ми можемо реалізувати усі ці варіанти з одним і тим же іменем, але різними параметрами. І першим я пропоную описати метод без параметрів, який буде ініціалізувати усе з встановлених значень:

procedure TGOEngine.Init;
begin
  //поки ще нічого не ініціалізовано, ознаку виконання ставимо в false
  fRunning:=false;
  //спочатку пробуємо ініціалізувати бібліотеку
  if SDL_Init(SDL_INIT_EVERYTHING)>=0 then begin
    //якщо все пройшло добре - створюємо вікно
    //прописуємо потрібні прапорці для вікна
    fWindowFlags:=SDL_WINDOW_RESIZABLE OR SDL_WINDOW_SHOWN;
    if IsFullScreen then fWindowFlags:=fWindowFlags OR SDL_WINDOW_FULLSCREEN;
    //пробуємо створити вікно
    fSDLWindow:=SDL_CreateWindow(PChar(Utf8String(Caption)),
                   SDL_WINDOWPOS_UNDEFINED,
                   SDL_WINDOWPOS_UNDEFINED,
                   Height,Width,
                   fWindowFlags);
    //якщо вікно створене, потрібно створити рендерер
    //прописуємо для нього прапорці
    fRendererFlags:=0;
    if HardwareAcceleration then fRendererFlags:=fRendererFlags OR SDL_RENDERER_ACCELERATED;
    if fSDLWindow<>nil then begin
       fSDLRenderer:=SDL_CreateRenderer(fSDLWindow,-1,fRendererFlags);
       if fSDLRenderer<>nil then begin
          New(fSDLEvent);//потрібно виділити пам’ять для вказівника
          fRunning:=true; //ознака виконання робочого циклу
          Exit;
       end;
    end;
  end;
end;

Як бачиш, відмінностей від попереднього варіанту ініціалізації небагато - немає встановлення значень полів класу та додалась ініціалізація прапорців для вікна та рендерера і підстановка їх у відповідні місця.

Тепер настала черга змінити варіант методу з передачею параметрів. Оскільки параметрів трохи побільшало, потрібно розширити їхній список. Код, який відповідає за ініціалізацію, ми вже прописали в методі вище і дублювати його немає потреби. Просто встановимо значення відповідних полів з параметрів і викличемо попередній перегружений метод:

procedure TGOEngine.Init(aCaption : String; _height, _width : Integer; Accelerated : Boolean = true; Fullscreen : Boolean = true);
begin
   Caption:=aCaption;
   Height:=_height;
   Width:=_width;
   HardwareAcceleration := Accelerated;
   IsFullScreen:=Fullscreen;
   Init;
end;

І нарешті останній перегружений метод, який буде читати настройки з файла. Я зупинився на форматі файла INI - він дуже простий і добре підтримується в усіх системах. Для комфортної роботи з цим форматом необхідно пвдключити модуль INIFiles. В якості параметрів методу будуть передаватись ім’я файлу та назва секції з настройками:

procedure TGOEngine.Init(aFile : TFilename; aSection : String);
 var INI : TINIFile;
begin
  INI := TIniFile.Create(aFile);
  Height:=INI.ReadInteger(aSection,’Height’,Height);
  Width:=INI.ReadInteger(aSection,’Widht’,Width);
  Caption:=INI.ReadString(aSection,’Caption’,Caption);
  IsFullScreen:=INI.ReadBool(aSection,’FullScreen’,IsFullScreen);
  HardwareAcceleration:=INI.ReadBool(aSection,’HardwareAcceleration’,HardwareAcceleration);
  INI.Free;
  Init;
end;

Як бачиш, все досить просто. Навіть в тому випадку, якщо файл настройок відсутній, значення полів залишаться без змін і програма зможе коректно працювати далі.

Оскільки можна настройки брати з файлу, логічно було б їх і зберігати в файл - в багатьох відеоіграх користувач може змінювати настройки і зберігати їх. Пропоную зробити аналогічний метод, який буде записувати поточні настройки вікна в файл:

function TGOEngine.SaveSettings(aFile: TFilename; aSection: String): Boolean;
var INI : TIniFile;
begin
  result := false;
  try
   INI := TIniFile.Create(aFile);
   INI.WriteInteger(aSection,’Height’,Height);
   INI.WriteInteger(aSection,’Widht’,Width);
   INI.WriteString(aSection,’Caption’,Caption);
   INI.WriteBool(aSection,’FullScreen’,IsFullScreen);
   INI.WriteBool(aSection,’HardwareAcceleration’,HardwareAcceleration);
   Result := true;
  finally
   INI.Free;
  end;
end;

Думаю, особливих пояснень ця функція не потребує - код говорить сам за себе. У випадку, якщо настройки не вдається записати, функція коректно обробляє ексцепшен і повертає false, не перериваючи роботу програми.

Ми багато доробили до нашого класу, але код тестової програми не міняли зовсім (за виключеням коли потрібно було потестити нові фішки які ми дописували). Такий підхід до розробки дуже практичний, оскільки при нових версіях фреймворку не доведеться міняти багато коду в іграх, які будуть створені на його основі.

В основному як працювати з вікном ми вияснили і зробили досить зручний клас, який при потребі можна буде досить просто вдосконалити, додавши необхідні додаткові властивості і не ламаючи при цьому існуючий код. В наступній частині почнемо прцювати з графікою і виводити зображення на екран.

Сирці до цієї статті можна скачати тут.

Розробка фреймворка для 2-Д відеоігор на основі мультимедійної бібліотеки SDL2 Частина 3. Вдосконалюємо роботу з вікном.

Розробка фреймворка для 2-Д відеоігор на основі мультимедійної бібліотеки SDL2

Частина 3. Вдосконалюємо роботу з вікном.

Оптимізація класу

В попередній частині ми створили каркасний клас для фреймворка, який створює вікно засобами SDL2. Проте для комфортної роботи цей клас потрібно вдосконалити, використовуючи можливості бібліотеки SDL2 для роботи з вікнами.

В останньому варіанті коду я допустив помилку: код, який відповідає за ініціалізацію, виніс в конструктор класу, а потрібно було його описати в методі Initialize. В новому варіанті класу ми цю помилку виправимо, а також розширимо можливості створення та керування вікном.

Щоб не заплутуватись в лістингах, надалі я не буду приводити код повністю після кожної зміни, а лише сніпети коду, який додається або змінюється

І ще одна особливість, яку я виявив при виведенні заголовку вікна: для того, щоб коректно відображалась кирилиця, потрібно використовувати тип UTF8String, який приводиться до типу PChar. Але для того, щоб такий метод відпрацьовував коректно, заголовок вікна винесемо окремою властивісю класу:

//заголовок вікна
    property Caption : String;
    

Натискуй Ctrl+Shift+C і Lazarus сам створить весь додатковий код, тобі лише потрібно зробити виправлення в методі Init(): рядок

fSDLWindow:=SDL_CreateWindow(PChar(аCaption),SDL_WINDOWPOS_UNDEFINED,SDL_WINDOWPOS_UNDEFINED,_height,_width,SDL_WINDOW_SHOWN);

потрібно замінити на наступні рядки:

fSDLWindow:=SDL_CreateWindow(PChar(Utf8String(Caption)),
                  SDL_WINDOWPOS_UNDEFINED,
                  SDL_WINDOWPOS_UNDEFINED,
                  Height,Width,
                  SDL_WINDOW_SHOWN);
   

Тепер значення заголовку буде зберігатися у відповідній властивості класу і коректно відображатись на екрані.

Аналогічно винесемо розміри вікна у окремі властивості класу Width і Height:

//ширина і висота вікна
    property Width : Integer;
    property Height : Integer;
 

Теж натискуй Ctrl+Shift+C щоб Lazarus автоматично завершив код і поки що ці методи лишай без змін, до них ми повернемось трохи пізніше.

Ще, на мою думку, зручно було б винести обробку робочого циклу теж окремим методом (аналогічно як в класі Application в LCL). Тож я вирішив додати метод Run:

procedure TGOEngine.Run;
begin
 while IsRunning do begin
    DoEvents;
    Render;
   end;
end;

Відповідно в тестовій програмі весь цикл while потрібно замінити лише одним рядком TestEngine.Run. Можеш спробувати запустити програму і переконатись, що все працює так як і раніше.

Повноекранний режим SDL

Для створення вікна бібліотека SDL використовує певний набір параметрів. Це ширина і висота вікна, початкові координати верхнього лівого кута вікна, а також набір різних додаткових ознак. Якщо звернутись до документації по SDL, то можна використовувати наступні ознаки:

Ознака	Призначення
SDL_WINDOW_FULLSCREEN	Вікно повинне бути на весь екран
SDL_WINDOW_OPENGL	Вікно може використовуватись як контекст OpenGL
SDL_WINDOW_SHOWN	Вікно видиме на екрані
SDL_WINDOW_HIDDEN	Вікно сховане
SDL_WINDOW_BORDERLESS	Вікно не має обрамлення і заголовку
SDL_WINDOW_RESIZABLE	Вікно може змінювати розміри
SDL_WINDOW_MINIMIZED	Вікно згорнуте
SDL_WINDOW_MAXIMIZED	Вікно розгорнуте
SDL_WINDOW_INPUT_GRABBED	Вікно захопило фокус вводу
SDL_WINDOW_INPUT_FOCUS	Вікно має фокус вводу
SDL_WINDOW_MOUSE_FOCUS	Вікно має фокус вказівника мишки
SDL_WINDOW_FOREIGN	Вікно створене не бібліотекою SDL

Оскільки більшість відеоігор зручніше грати в повноекранному режимі, нас цікавить сама перша ознака SDL_WINDOW_FULLSCREEN. Спробуй змінити ознаку в функції створення вікна в методі Init() нашого класу і подивись результат. Щоб закрити вікно в повноекранному режимі, натисни Alt+F4, оскільки заголовок зі стандартними кнопками відсутній.

Проте періодично виникають ситуації, коли потрібно швидко переключитись між повноекранним/віконним режимами без виходу з програми. SDL дозволяє таке зробити за допомогою функції SDL_SetWindowFullscreen(), яка в якості параметрів приймає вікно, з яким відбувається дія, та ознаку 0 для віконного режиму або 1 для повноекранного.

Отже, для встановлення ознаки повноекранного режиму я ввів ще одну властивість:

property IsFullScreen : Boolean default true;

після чого натиснув вже добре знайому комбінацію Ctrl+Shift+C для автоматичного завершення коду. Далі, переходимо в згенерований Лазарусом внутрішній метод SetIsFullScreen() і в кінці додаємо наступні рядки коду:

if FIsFullScreen then SDL_SetWindowFullscreen(fSDLWindow,SDL_WINDOW_FULLSCREEN)
    else SDL_SetWindowFullscreen(fSDLWindow,0);
  SDL_UpdateWindowSurface(fSDLWindow);

Цей код реалізує перехід в повноекранний або віконний режим в залежності від поточного значення поля FIsFullScreen. Останній рядок необхідний для того, щоб вікно обновилось після зміни режиму.

Добре, код для реалізації зміни режиму вже є, тепер потрібно назначити коли цей код повинен виконуватись. В більшості програм для переключення між віконним та повноекранним режимами прийнято використовувати комбінацію клавіш Alt+Enter. Я вирішив теж реалізувати переключення між режимами цією комбінацією клавіш, і мене переклинило більше ніж на годину часу. Справа в тому, що потрібно відловити натискання комбінації клавіш, а за один раз вдається відловити лише натискання однієї клавіші. Звісно, є ще можливість перевірити які з клавіш-модифікаторів були в цей час натиснуті, але конкретного прикладу як це правильно зробити я знайти так і не зміг (навіть для C++!), тож довелось практичним шляхом виясняти самому.

Спочатку потрібно відловити подію натискання клавіш. Бібліотека SDL для цього має два типа подій, які виникають перша при натисканні клавіші, а друга при відпусканні. В нашому випадку краще підходить подія відпускання клавіші. Переходь в метод DoEvents() та після рядка

if fSDLEvent^.type_ = SDL_QUITEV then fRunning:=false;
      

додай наступний код:

if (fSDLEvent^.type_ = SDL_KEYUP) then begin
         //відловлюємо Alt+Enter для зміни режиму
         if (fSDLEvent^.key.keysym.sym = SDLK_RETURN) and ((fSDLEvent^.key.keysym._mod and KMOD_ALT) <> 0) then
            IsFullScreen:=not IsFullScreen;
      end

Спробуй запустити та потестити - повинно все працювати саме так, як і задумано. Якщо щось не виходить чи не можеш зрозуміти що куди в коді потрібно прописати, можеш скачати архів з сирцями (лише у властивостях проекту потрібно поправити шляхи до трансльованих заголовочних файлів SDL2, про що я писав ще в першій статті). В наступній частині ми завершимо рутинну роботу з вікном і поступово почнемо переходити до виведення зображень. А на сьогодні поки що все. Всі зауваження та побажання до статті пишіть в коментарях.

Розробка фреймворка для 2-Д відеоігор на основі мультимедійної бібліотеки SDL2 Частина 2. Перше вікно SDL2.

Розробка фреймворка для 2-Д відеоігор на основі мультимедійної бібліотеки SDL2

Частина 2. Перше вікно SDL2.

В попередній частині ми підготували усе необхідне для створення ігрового фреймворку на основі мультимедійної бібліотеки SDL2, а тепер почнемо роботу безпосередньо над самим фреймворком.

Оскільки сам термін “відеогра” передбачає виведення на екран, відповідно, основою для відеогри буде екран або якась його частина, у нашому випадку вікно. Спочатку я покажу тобі, яким способом можна отримати вікно за допомогою бібліотеки SDL2. Оскільки ми не будемо використовувати LCL, нам не потрібно нічого лишнього, тому в Lazarus створи новий проект типу “Проста програма”, і набери наступний код:

{******************************}program demo;{*********************************}
{*                                                                            *}
{*     Демонстрація створення пустого вікна за допомогою бібліотеки SDL2      *}
{*                                                                            *}
{******************************************************************************}
 {$mode objfpc}
uses sdl2;

 var SDLWindow   : PSDL_Window;
     SDLRenderer : PSDL_Renderer;
     SDLEvent    : PSDL_Event;
     isRun       : Boolean;

begin
   //спочатку пробуємо ініціалізувати бібліотеку
   if SDL_Init(SDL_INIT_EVERYTHING)>=0 then begin
      //якщо все пройшло добре - створюємо вікно
     SDLWindow:=SDL_CreateWindow('Game over!',SDL_WINDOWPOS_UNDEFINED,SDL_WINDOWPOS_UNDEFINED,640,480,SDL_WINDOW_SHOWN);
     //якщо вікно створене, потрібно створити рендерер
     if SDLWindow<>nil then begin
        SDLRenderer:=SDL_CreateRenderer(SDLWindow,-1,0);
        if SDLRenderer=nil then begin
           SDL_ShowSimpleMessageBox(SDL_MESSAGEBOX_ERROR,'Error!',SDL_GetError,SDLWindow);
           Exit;
        end;
     end;
     New(SDLEvent);
     isRun:=true; //ознака виконання робочого циклу
     while isRun do begin
          //встановлюємо колір вікна в голубий
          SDL_SetRenderDrawColor(SDLRenderer,0,128,255,255);
          //очищаємо вікно
          SDL_RenderClear(SDLRenderer);
          //показуємо вікно на екрані
          SDL_RenderPresent(SDLRenderer);
          //відловлюємо подію закриття вікна
          if SDL_PollEvent(SDLEvent)=1 then begin
              if SDLEvent^.type_ = SDL_QUITEV then isRun:=false;
          end;
     end;
     //прибираємо за собою
     Dispose(SDLEvent);
     SDL_DestroyRenderer(SDLRenderer);
     SDL_DestroyWindow(SDLWindow);
     //зупиняємо бібліотеку
     SDL_Quit;
   end;
end.

Я не буду в деталях зупинятись на описі кожної функції бібліотеки SDL2, ця інформація доступна як в сирцях трансляції заголовочних файлів, так і на багатьох сайтах. Розглянемо лише що робить цей код.

Для створення вікна нам необхідні наступні змінні: для вікна, рендерера (це така штука, яка відповідає за малювання зображення), відловлювання подій SDL2 та ознака виконання робочого циклу.

Після ініціалізації усіх підсистем SDL2 створюємо спочатку вікно, тоді рендерер. У випадку, якщо не вдається створити рендерер, програма виводить відповідне повідомдення і перериває виконання.

Коли все пройшло успішно, ми маємо вікно і рендерер, який на ньому буде промальовувати все, що нам потрібно.

Для того, щоб вікно можна було закрити, ми мусимо відловити відповідну подію SDL2. Оскільки спеціальної функції для ініціалізації змінної для роботи з повідомленнями немає, потрібно просто виділити для цього пам’ять стандартною функцією Pascal New(). Встановленням ознаки виконання робочого циклу в true завершується розділ ініціалізації і починається безпосередньо робочий цикл.

Сам цикл буде тривати до того моменту, поки змінна isRun буде мати значення true. Все, що в нас вібувається з кожною ітерацією циклу - встановлення кольору для вікна, заливка вікна цим кольором і показ його на екрані, після чого йде відловлювання події SDL2 і перевірка чи це саме та подія, яка нам потрібна. І коли нарешті настає момент закриття вікна, ми відловлюємо відповідну подію SQL_QUITEV. Змінна isRun приймає значення false і виконання циклу перериваєьтся. Програма переходить до наступної стадії - очистка використаної пам’яті. Усі змінні очищаємо в порядку, оберненому до порядку їх створення: спочатку звільняємо пам’ять, виділену під вказівник змінної для відловлювання подій, тоді рендерер, вікно і зупиняємо усі підсистеми SDL2.

Варто пам’ятати: усі змінні, які ініціалізуються функціями типу SDL_CreateXXX(), звільняються відповідними функціями SDL_DestroyXXX() в порядку, оберненому до порядку їх ініціалізації. Ті змінні, пам’ять для яких виділялась явно функцією New(), повинні очишатись теж в оберненому порядку функцією Dispose().

Здається, тут все досить просто, але й близько не видно, яке це має відношення до ігрового фреймворку. Що ж, давай тепер розглянемо, за яким принципом побудовані усі відеоігри.

Ігровий алгоритм, або з чого складається відеогра

Незалежно від жанру, ігрового дизайну, сукупності використовуваних технологій, ігрова механіка будь-якої відеогри складається із взаємодії різних підсистем, таких як графіка, ігрова механіка і ввід корисувача. При цьому графічна підсистема може нічого не знати про логіку гри, яким чином відбувається введення користувачем, тощо. Ми можемо думати про структуру гри наступним чином:

Рис.1. Типовий алгоритм будь-якої гри.

Після одноразової ініціалізації усіх необхідних даних запускається ігровий цикл, який перевіряє ввід користувача, прораховує ігрову логіку і встановлює необхідні значення усіх об’єктів і змінних до того, як вивести графіку на екран.

Коли користувач вибирає завершити гру, ігровий цикл переривається, і гра переходить до стадії очищення даних та виходу.

Спробуємо розділити попередній код на окремі логічні блоки, які будуть відповідати за усі перечислені кроки:

{******************************}program demo_v2;{*********************************}
{*                                                                            *}
{*     Демонстрація створення пустого вікна за допомогою бібліотеки SDL2      *}
{*                                                                            *}
{******************************************************************************}
 {$mode objfpc}
uses sdl2;

 var SDLWindow   : PSDL_Window;
     SDLRenderer : PSDL_Renderer;
     SDLEvent    : PSDL_Event;
     isRun       : Boolean;

 function Initialize(aCaption : PChar; _height, _width : Integer) : Boolean;
 //ініціалізація SDL2 і створення вікна та рендерера
 begin
   result:=false;
   //спочатку пробуємо ініціалізувати бібліотеку
   if SDL_Init(SDL_INIT_EVERYTHING)>=0 then begin
      //якщо все пройшло добре - створюємо вікно
     SDLWindow:=SDL_CreateWindow(aCaption,SDL_WINDOWPOS_UNDEFINED,SDL_WINDOWPOS_UNDEFINED,_height,_width,SDL_WINDOW_SHOWN);
     //якщо вікно створене, потрібно створити рендерер
     if SDLWindow<>nil then begin
        SDLRenderer:=SDL_CreateRenderer(SDLWindow,-1,SDL_RENDERER_ACCELERATED);
        if SDLRenderer<>nil then begin
           New(SDLEvent);//потрібно виділити пам'ять для вказівника
           isRun:=true; //ознака виконання робочого циклу
           Result:=true;
           Exit;
        end;
     end;
   end;
 end;

procedure DoEvents;
begin
 //відловлюємо подію закриття вікна
  if SDL_PollEvent(SDLEvent)=1 then begin
     if SDLEvent^.type_ = SDL_QUITEV then isRun:=false;
  end;
end;

procedure Draw;
begin
  //встановлюємо колір вікна в бірюзовий
  SDL_SetRenderDrawColor(SDLRenderer,0,128,255,255);
  //очищаємо вікно
  SDL_RenderClear(SDLRenderer);
  //показуємо вікно на екрані
  SDL_RenderPresent(SDLRenderer);
end;

procedure Cleanup;
begin
  //прибираємо за собою
  Dispose(SDLEvent);
  SDL_DestroyRenderer(SDLRenderer);
  SDL_DestroyWindow(SDLWindow);
  //зупиняємо бібліотеку
  SDL_Quit;
end;

begin
   //спочатку пробуємо ініціалізувати бібліотеку
   isRun:= Initialize('Game over! v.2.0',640,480);
   if not isRun then begin
           SDL_ShowSimpleMessageBox(SDL_MESSAGEBOX_ERROR,'Error!',SDL_GetError,SDLWindow);
           Exit;
    end;
   while isRun do begin
     DoEvents;
     Draw;
   end;
   Cleanup;
end.

Коли ти запустиш цей код на виконання, то побачиш, що кінцевий результат не змінився, створюється те ж саме вікно, але тепер є окремі чітко виділені підпрограми для ініціалізації, обробки подій, рендерингу і очистки пам’яті. Це вже ближче до того, що нам потрібно. Не вистачає лише підпрограми для обчислення усієї ігрової логіки. Крім цього, такий підхід при розробці гри є не дуже гнучким, оскільки на кожну нову гру доведеться по новомо все це описувати. Це не наш метод, я хочу отримати в результаті фреймворк, який мені буде спрощувати написання коду і дозволить зосередитись безпосередньо на написанні гри, а не рутини по створенню вікон, обробці подій, виведенні на екран тощо. Для цього давай опишемо окремий клас, який стане основою для майбутнього фреймворку.

Оскільки ми вже впритул підійшли до написання фреймворку, потрібно придумати йому назву. Я пропоную “Game Over 2D Engine”, ти можеш придумати іншу назву.

Повернемось до нашого коду. Оскільки це буде базовий клас, я назвав його TGOEngine (скорочено від Game Over), і ось що в мене в результаті вийшло:

unit ugoengine;

{$mode objfpc}{$H+}

interface

uses sdl2;

type

 { TGOEngine }

 TGOEngine =class
  private
    fWindow   : PSDL_Window;
    fRenderer : PSDL_Renderer;
    fError    : Boolean; //якщо відбулась помилка
    fIsRun    : Boolean; //чи запущений ігровий цикл
  public
    constructor Create;
    destructor Destroy;override;

    procedure Initialize(aCaption : PChar; _height, _width : Integer);
    procedure DoEvents;
    procedure Update;
    procedure Draw;
  published
    property Error : Boolean read fError;
    property IsRunning : Boolean read fIsRun;
  end;

implementation

{ TGOEngine }

constructor TGOEngine.Create;
begin
  inherited Create;
  //ініціалізація SDL2 і створення вікна та рендерера
   begin
     fError:=true;
     //спочатку пробуємо ініціалізувати бібліотеку
     if SDL_Init(SDL_INIT_EVERYTHING)>=0 then begin
        //якщо все пройшло добре - створюємо вікно
       fWindow:=SDL_CreateWindow('Game over!',SDL_WINDOWPOS_UNDEFINED,SDL_WINDOWPOS_UNDEFINED,640,480,SDL_WINDOW_SHOWN);
       //якщо вікно створене, потрібно створити рендерер
       if fWindow<>nil then begin
          fRenderer:=SDL_CreateRenderer(fWindow,-1,0);
          if fRenderer<>nil then begin
             fError:=false;
             Exit;
          end;
       end;
     end;
   SDL_ShowSimpleMessageBox(SDL_MESSAGEBOX_ERROR,'Error',SDL_GetError,fWindow);
   end;
end;

destructor TGOEngine.Destroy;
begin
   //прибираємо за собою
   SDL_DestroyRenderer(fRenderer);
   SDL_DestroyWindow(fWindow);
   //зупиняємо бібліотеку
   SDL_Quit;
   inherited Destroy;
end;

procedure TGOEngine.Initialize(aCaption : PChar; _height, _width : Integer);
begin
  //тут буде проходити ініціалізація даних
   fIsRun:=true;
end;

procedure TGOEngine.DoEvents;
var _Event : PSDL_Event;
begin
   New(_Event);
  //тут буде проходити обробка подій
   if SDL_PollEvent(_Event)=1 then begin
      case _Event^.type_ of
SDL_QUITEV: fIsRun:=false;
      end;//case
   end;
   Dispose(_Event);
end;

procedure TGOEngine.Update;
begin
  //тут буде оновлюватись поточний стан виконання
end;

procedure TGOEngine.Draw;
begin
  if fError then Exit;
  //встановлюємо колір вікна в бірюзовий
  SDL_SetRenderDrawColor(fRenderer,0,128,255,255);
  //очищаємо вікно
  SDL_RenderClear(fRenderer);
  //показуємо вікно на екрані
  SDL_RenderPresent(fRenderer);
end;


end.

А ось код основної програми:

{******************************}program demo_v3;{*********************************}
{*                                                                            *}
{*     Демонстрація створення пустого вікна за допомогою бібліотеки SDL2      *}
{*                                                                            *}
{******************************************************************************}
 {$mode objfpc}{$H+}

uses ugoengine;

var TestEngine : TGOEngine;

begin
   //створюємо екземпляр класу
   TestEngine:=TGOEngine.Create;
   //ініціалізуємо початкові дані
   TestEngine.Initialize('Game Over v.3.0',640,480);
   while TestEngine.IsRunning do begin;
    TestEngine.DoEvents;
    TestEngine.Update;
    TestEngine.Draw;
   end;
   TestEngine.Free;
end.

Як бачиш, використання класу дозволяє не думати про рутину створення вікна і зосередитись лише над тим, що ти хочеш отримати в результаті. Проте цей клас ще не забезпечує усієї потрібної роботи з вікном і рендерером. Спробуємо його вдосконалити в наступній частині.

Вчимося програмувати!

Вітаю Вас у своєму блогові, присвяченому вивченню програмування!

Якщо Ви читаєте цей текст, то:

• Вас цікавить програмування?
• Вам подобаються комп'ютерні ігри?
• Ви хотіли б навчитися створювати власні комп'ютерні ігри (і не лише для комп'ютерів)?
• Ви не знаєте, з чого почати?

Якщо хоча б на два питання Ви відповіли "так", то мій блог Вам в цьому допоможе.
Мої уроки відрізняються від інших тим, що весь матеріал я буду викладати орієнтуючись на розробку ігор. Для навчання будемо використовувати мову програмування Object Pascal. Інструменти, які нам будуть необхідні - це компілятор Free Pascal Compiler та інтегроване середовище розробки Lazarus або CodeTyphoon IDE.
Напевно, Вас цікавить питання, чому саме я вирішив побудувати свої уроки орієнтовно розробки ігор? Відповідь проста - так набагато цікавіше і легше вивчити основи. Комп'ютерна гра - це теж програма, при розробці якої потрібно проходити усі етапи, від обдумування ідеї  та алгоритму до тестування та випуску готового релізу. На мою думку, сам процес розробки гри не менш цікавий, ніж грати у вже готову гру, а можливо, навіть і цікавіший. Граючи чужі ігри, ми змушені підпорядковуватись чужим правилам, створюючи власну гру - правила задаємо ми самі, і вже інші будуть змушені підпорядковуватись нашим правилам.
Мої уроки не претендують на повноту розкриття матеріалу, я спробую пояснити лише основи, тому варто буде користуватись додатковими матеріалами, про що я буду зазначати у відповідних місцях з посиланням на рекомендовані джерела.
Вже зовсім скоро ми почнемо, і найперше, що нам доведеться зробити - познайомитись з інструментами, якими будемо користуватись. Це і буде темою першого уроку.